大牛有形
2013-11-23 14:09:27| 分类:
股票编程
| 标签:
|举报
|字号大中小 订阅
{大牛有形};
{常数}
T1:=COUNT(DATE-REF(DATE,1)=1,10)>=3;{DAY日}
T2:=COUNT(BETWEEN(DATE-REF(DATE,1),5,10),10)>=3;{WEEK周}
T3:=COUNT(DATE-REF(DATE,1)>95,10)>=3;{MONTH月}
T:=IF(T1+2*T2+3*T3=0,1,T1+2*T2+3*T3);{TIME}
LG:=120/T;{LONG长期}
M:=60/T;{MID中期}
N:=30/T;{MID & SHORT中短期}
M1:=0.96-T/100;M2:=1.04+T/100;{MA NEAR 均线近}
{MA均线}
MA5:=MA(C,5); MA5_UP:=MA5>REF(MA5,1); {MA5}
MA21:=MA(C,21); MA21_UP:=MA21>REF(MA21,1); {MA21}
MA55:=MA(C,55); MA55_UP:=MA55>REF(MA55,1); {MA55}
MA120:=MA(C,120); MA120_UP:=BETWEEN(MA120/REF(MA120,5),0.999,1.002); {MA120}
{KDJ随机}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1); {K}
D:=SMA(K,3,1);{D}
J:=3*K-2*D;{J}
{MACD差异}
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26); DIF_UP:=DIF>REF(DIF,1); {DIF}
DEA:=EMA(DIF,9); DEA_UP:=DEA/REF(DEA,2)>1.01; {DEA}
MACDBAR:=(DIF-DEA)*2;
{BOLL布林}
BOLLM:=MA21;
BOLLU:=BOLLM+2*STD(C,21);
BOLLL:=BOLLM-2*STD(C,21);
{************************************************************}
{K形态};
{************************************************************}
{长期横盘后突破};
C1:=HHV(C,M)/LLV(C,M)<1.2 OR HHV(C,N)/LLV(C,N)<1.1;
C2:=COUNT(BETWEEN(MA21,H,L),M)>15 AND COUNT(BETWEEN(MA21,H,L),5)>=1;
C3:=MA5_UP AND MA21_UP AND MA55_UP AND MA120_UP AND (C>MA55 OR C>MA120);{长期均线走平}
横突:C1 AND C2 AND C3;
{************************************************************}
{MA形态};
{************************************************************}
{MA会聚后突破};
C4:=BETWEEN(MA5/MA55,M1,M2) AND BETWEEN(MA21/MA55,M1,M2)
AND BETWEEN(MA55/MA120,M1,M2);
聚突:C3 AND C4 ;
{MA金叉或顺叉};
C5:=CROSS(MA21,MA55) AND MA55_UP;
C6:=MA21_UP AND MA55_UP AND REF(MA21,3)>REF(MA21,1)
AND BETWEEN(MA21/MA55,M1,M2);
MA金顺: C5 OR C6;
{MA价托};
C7:=COUNT(CROSS(MA5,MA21),10)=1 AND COUNT(CROSS(MA5,MA55),5)=1
AND CROSS(MA21,MA55);
价托:C7;
{************************************************************}
{MACD形态};
{************************************************************}
{MACD金叉或顺叉};
C8:=CROSS(DIF,DEA) AND DEA>-0.15 AND DEA_UP;
C9:=CROSS(DIF,DEA) AND T>1 AND 1;
C10:=DIF_UP AND DEA_UP AND REF(DIF,5)>REF(DIF,1) AND DIF>DEA;
CD金顺: C8 OR C9 OR C10;
{MACD二次金叉且金叉点上升};
T_MACD:=REF(BARSLAST(CROSS(DIF,DEA) OR C10),1)+1;{MACD上次金叉到今天金叉T}
CD二次金叉:(CROSS(DIF,DEA) OR C10) AND DEA>REF(DEA,T_MACD) AND REF(DEA,T_MACD)<0;
选股:横突 OR 聚突 OR MA金顺 OR 价托 OR CD金顺 OR CD二次金叉;
评论这张
转发至微博
转发至微博
评论